6.2.10  Tools組件
       Tools組件提供了一些有用的方法，可在頁面中檢查文件是否存在、處理一個HTML窗體、以及產生一個隨機整數，還有用于Macintosh計算機的一些方法，還可以檢查是否存在某個服務器插件以及檢查用戶是否是網站的擁有者。
1．  Tools組件的成頁
Tools組件提供了五個方法，其中兩個依賴于操作系統，如表6-8所示：
表6-8  Tools組件的方法及說明
方 法
說 明

FileExists(relative_url)
如果relative_url指定的文件存在，返回值為True，否則為False。必須給出虛擬相對路徑及文件名，并且文件必須存在于發布的Web網站目錄中。

Random()
產生一個位于-32768~32767之間的隨機整數。使用ABS函數（VBScript）或Math.abs（JScript）得到在0~32768之間的正整數。使用Mod運算符（VBScript）或%運算符（JScript）得到指定范圍內的一個數值。例如：
intRand = (objTools.Random Mod 76) + 25
得到一個在25~100之間的整數。

ProcessForm(output_url,
template_url,[insertion_point])
通過template_url指定的文件處理一個HTML窗體，并且插入來自窗體中已提交給當前頁面的數值。結果寫進 output_url指定的文件，如果指定了可選項insertion_point（字符串）參數的話，組件可在已存在的輸出文件中找到這個字符串，并在該位置插入新的內容。如果insertion_point參數沒有指定，任何已存在的 output_url文件則被新的輸出取代

Owner
僅適用于Macintosh機，如果當前用戶帳戶是Web網站的擁有者，返回值為True，否則返回值為False

PluginExists(plugin_name)
僅適用于Macintosh機，如果指定的服務器plugin_name安裝在機器上，返回值為True，否則為 False

2．  使用FileExists方法
在允許用戶訪問之前，可以使用FileExists方法檢查某些文件是否存在于服務器中（注意這個方法和 FileSystemObject.FileExists以同樣的方式工作）。
下面的例子中，用戶提供了網頁的相對URL，如果用戶想通過在名為txtURL的文本框中鍵入URL打開網頁，在重新定向之前可以檢查其是否存在。
       <% // in Jscript:
       var objTools = Server.CreateObject('MSWC.Tools');
       var strURL = Request.Form ('txtURL');         // collect the page URL they entered
       if (objTools.FileExists(strURL))                  // see if it exists
              Server.Transfer(strURL)                    ;      // if it does, transfer to it
       Else          & nbsp;                                     ;           // or if not display a message
              Response.Write('Sorry, the page you requested does not exist');
       %>
       這里提供了一個示例頁面（使用VBScript）來演示組件的三種方法（非 Macintosh），可以從ASP Installable Components主菜單中運行，如圖6-16所示：

圖6-16  運行Tools組件的方法的頁面
       網頁的第一部分允許輸入一個文件的相對URL，并告訴用戶該文件是否存在。示例提供的缺省值是查看網站的根目錄中是否有global.asa文件。點擊按鈕時，說明該文件是否可找到的信息將放在頁面的頂部，如圖6-17所示：

圖6-17  運行FileExists方法的結果
       把頁面的所有控件放在<FORM>中，提交回本頁面，這已經成為一種規范。在頁面的開始，查看點擊了哪個按鈕。如果是FileExists的按鈕，就調用組件的FileExists方法并顯示合適的信息。
       'look for a command sent from the FORM section buttons
If Len(Request.Form("cmdExists")) Then
  strFile = Request.Form("txtFile")
  If objTools.FileExists(strFile) Then
    Response.Write "The file '<B>" & strFile & "</B>' does exist.<P>"
  Else
    Response.Write "The file '" & strFile & "' <B>does not</B> exist.<P>"
  End If
End If
3．使用Tools.Random方法
在ASP頁面中，有時需要一個隨機數來完成某些任務，例如，把用戶重新定位到一個隨機網頁、選擇顏色或顯示每日提示�？梢允褂肰BScript中的Rnd函數，但要把所得數值轉變成指定范圍內的整數。Tools組件的Random方法更易于使用，因為能夠直接提供整數值。
Random方法的結果是一個在-32768~32767范圍中的整數值，為了獲得一個指定范圍的整數，可以使用腳本語言中的Abs函數并對下一個最大的整數取模。例如為了用VBScript語言創建0~20的正整數，可以使用下列語句：
intRandom = Abs(objTools.Random) Mod 21
為了得到在50~100之間的數值，可以用：
intRandom = (Abs(objTools.Random) Mod 51) + 50
示例網頁使用這項技術生成隨機數時，首先需要檢查由用戶輸入的數值，以保證這些數值既是有效正整數又有正確的相對關系。
If Len(Request.Form("cmdRandom")) Then
  intMin = -1  'preset to illegal values and then
  intMax = -1  'only set if a valid number is entered
  strMin = Request.Form("txtMinimum")
  strMax = Request.Form("txtMaximum")
  If IsNumeric(strMin) Then intMin = CStr(strMin)
  If IsNumeric(strMax) Then intMax = CStr(strMax)
  If (intMin >= 0) And (intMax > intMin) Then
    intRandom = (Abs(objTools.Random) Mod (intMax - intMin + 1)) + intMin
    Response.Write "Your random value is: <B>" & intRandom & "</B><P>"
  Else
    Response.Write "<B>The numbers you entered are not valid.</B><P>"
  End If
End If
當頁面重新調入時，結果顯示在網頁的頂部，如圖6-18所示：

圖6-18  運行Random方法的結果
4．使用Tools.ProcessForm方法
Tools組件中最復雜的方法是ProcessForm，用來讀取存在磁盤上的臨時文件，并在其中插入創建的信息（可能來自當前頁面的Request.Form集合的內容），然后把結果作為一個文件輸出到磁盤，這個方法的語法是：
ProcessForm (output_url, template_url, [insertion_point])
臨時文件和輸出文件相對于當前頁面使用相對URL來定義。輸出文件可以是ASP網頁，如果這樣，當其在瀏覽器打開時，將正常處理。臨時文件可以包含普通的ASP代碼，但不運行，僅簡單地拷貝輸出文件。然而，如果把臨時文件中的ASP代碼放在<%%…%%>限定符中，當臨時文件調入時代碼將被執行，這允許動態生成的數值（諸如進行處理的時間和日期）插入到輸出頁面中。
下面是示例文件template.asp（在chapter06目錄的Tools子目錄中）：
This file was created by the ASP Tools component
------------------------------------------------
The content of the request was:

Output file name: <%% = Request.Form("txtOutput") %%>
Template file name: <%% = Request.Form("txtTemplate") %%>
Insertion point text: <%% = Request.Form("txtInsert") %%>

------------------------------------------------
Created <%% = Now() %%>
示例頁面包含著預定使用這個臨時文件的控件，這些控件創建一個和臨時文件在同一個文件夾中的名為output.asp的輸出文件，如圖6-19所示：

圖6-19  運行Tools.ProcessForm方法的界面
點擊按鈕時，將運行一部分ASP代碼，從文本框中采集數據并調用ProcessForm方法：
If Len(Request.Form("cmdProcess")) Then
  strTemplate = Request.Form("txtTemplate")
  strOutput = Request.Form("txtOutput")
  strInsertPoint = Request.Form("txtInsert")
  '…
  ' we display the template contents here
  '…

  ' process the form contents
  objTools.ProcessForm strOutput, strTemplate, strInsertPoint

  '…
  ' we display the output file contents here
  '…
End If
(1)    設置輸出文件的訪問權限
如果得到一個“MSWC.Tools error 80004005 Couldn’t open output file”錯誤信息，這意味著IIS不允許向指定的目錄中寫入輸出文件。解決這個問題最快捷的方法是，在Properties對話框中的Security選項卡中，將相應的Tools目錄以及存放output.asp的目錄的Everyone組的Full Control設置成允許，如圖6-20所示：

圖6-20  設置輸出文件訪問權限的界面
(2)    查看文件內容
圖6-21顯示了上面代碼用缺省值運行缺省值運行的結果，可以看到原來的臨時文件內容，以及使用ProcessForm方法插入到輸出文件中的內容。

圖6-21  輸出文件的內容
這里省略了顯示來自前面見過的文件內容的程序代碼。顯示內容的方法與ASP Installable Components主菜單頁面中用于顯示內容鏈接列表文件的方法相同。使用FileSystemObject和TextStream對象的實例把整個文件讀入到一個字符串中，然后將其插入網頁中（記住要使用Server.HTMLEncode方法，以便把字符“<”和“>”轉換成可用于顯示的字符）。
QUOT = Chr(34)   'double-quote character
…
'create a FileSytemObject object to display the template file contents
Set objFSO = Server.CreateObject("Scripting.FileSystemObject")

Response.Write "The content of the template file <B>" & _
               strTemplate & "</B> is:"

Set objTStream = objFSO.OpenTextFile(Server.MapPath(strTemplate), ForReading)
strContent = Server.HTMLEncode(objTStream.ReadAll)   'read whole file
objTStream.Close

Response.Write "<DIV CLASS=" & QUOT & "showcode" & QUOT & "><PRE>" & _
               strContent & "</PRE></DIV>"
…
(3)    關于插入點參數
ProcessForm方法可選的insertion_point參數能用來在文件中的特定點插入文本，這個方法是先查找輸出文件中特定字符串的第一個實例，然后在該位置插入創建的新內容，在輸出文件中通過把星號（*）放在insertion_point字符串前面來放置新內容。如果省略了insertion_point參數，新的內容會取代整個輸出文件。
注意insertion_point參數在Tools.ProcessForm方法的早期版本中不能使用。